[정보] 부족한 스킬창, 매크로를 써 보자

다른 직업도 그렇지만 드루이드는 이번 확팩 들어 액체형상이 생기면서 스킬창 압박이 더 심해졌습니다

단축키는 한정되어 있고, 필요하다고 무작정 추가하자니 손은 꼬이고...

그래서 매크로를 활용해서 온몸비틀기를 해 보고자 합니다

- 들어가기에 앞서

와우의 매크로는 역사가 깊죠

그만큼 지식의 편차도 크고, 정보도 파편화가 심합니다

같은 기능을 하는 매크로인데 문법이 다른 경우도 많이 보입니다

(누군가는 /시전, 누군가는 /cast 등등)

그래서 일단 매크로에 대한 간단한 작동방식을 알아보고 가 봅시다 

추가) 이 글에서는 스크립트 수준의 매크로는 얘기하지 않습니다

매크로의 작동 방식에서 중요한건 세가지 입니다

1. 좌에서 우로, 위에서 아래로
2. 괄호에 정의하는 옵션은 AND와 OR가 있다
3. 스킬명은 정확하게 기입해야 한다

아래 예시를 통해 하나씩 봐 보도록 합시다

STEP>1. 좌에서 우로, 위에서 아래로

#showtooltip

/cast [nostance,harm] 천벌

/cast [known:후려갈기기,stance:1] 후려갈기기

/cast [stance:2] 칼날 발톱

/cast [known:회복,nostance,@mouseover,help][known:회복,help][] 회복 

차례대로 해석해 보자면

1줄) #showtooltip

매크로를 만들때 ? 아이콘을 선택하고 첫 줄에 해당 문구를 정해주면

현재 '표시되어야 하는' 스킬의 툴팁이 나타납니다

2줄) /cast [nostance,harm] 천벌

현재 특정 폼이 아니고, 선택 대상이 적일때 천벌

3줄) /cast [known:후려갈기기,stance:1] 후려갈기기

후려갈기기 스킬이 있고, 곰폼(스탠스-1)일때 후려갈기기

4줄) /cast [stance:2] 칼날 발톱

냥폼(스탠스-2)일떄 칼날 발톱

5줄) /cast [known:회복,nostance,@mouseover,help][known:회복,help][] 회복

1. 회복 스킬이 있고, 특정 폼이 아니고, 마우스오버 대상이 아군일때

2. 회복 스킬이 있고, 선택 대상이 아군일때

3. 조건없이 회복 

좀 더 자세하게 들여다 보면 이렇습니다

첫번째 줄의 #showtooltip은 위 매크로가 동작하면서 상태에 따라 스킬이 변할때마다 해당 스킬의 아이콘과 툴팁을 표시해주게 됩니다

별거 아닌것처럼 보이지만, 이처럼 여러 기능을 하는 매크로를 작성할 때에는 일종의 에러 체크로서 기능하기 때문에 상당히 유용합니다

두번째 줄 부터는 아마 이런 형태를 많이 보셨을겁니다

형태는 다르지만 근본적인 동작은 같습니다

/cast [nostance,harm] 천벌; [stance:1] 후려갈기기; [stance:2] 칼날 발톱 

그럼 대체 왜 표시 형태에 차이가 나는가?

매크로 구문은 좌에서 우로, 위에서 아래로 순서로 해석하여 작동하기 때문입니다

STEP>2. AND, OR 조건식

매크로는 간단한 방식의 논리연산을 제공합니다

단어는 거창하지만, 말로 풀어쓰면 이런 식입니다

[조건-1, 조건-2] = 조건-1 and 조건-2

[조건-1] [조건-2] = 조건-1 or 조건-2

[조건-1, 조건-2] [조건-3, 조건-4] = (조건-1 and 조건-2) or (조건-3 and 조건-4) 

이처럼 STEP-1의 규칙을 먼저 적용하고, 그 뒤 STEP-2의 논리연산이 적용되어 매크로가 작동합니다

그럼 이제 목표를 하나 설정해서 매크로를 작성해 봅시다

우리가 원하는 기능은 아래와 같습니다

1. 대상이 적이면 천벌
2. 마우스오버 대상이 아군이면 회복
3. 대상이 아군이면 회복
4. 곰폼이면서 후려갈기기가 있으면 후려갈기기
5. 곰폼이면서 후려갈기기가 없으면 회복
6. 냥폼이면 칼날 발톱

그런데, 매크로는 위에서 아래로 작동하기 때문에 이대로 작성하게 되면 1,2,3번이 먼저 적용되면서

폼에 상관없이 대상이 적이면 천벌, 마우스오버+대상이 아군이면 회복이 나가게 되고

우리가 원하는 곰폼 냥폼의 스킬 2가지는 사용이 되지 않습니다

그리고 특성에 따라 회복을 찍지 않는 경우도 있겠네요

게다가 천벌은 폼에 상관없이 무조건 천벌로 발동하기 때문에 이것도 수정이 필요하겠군요

그러니 순서와 조건을 살짝 조정해 봅시다

1. 인간폼이면서 대상이 적이면 천벌
2. 후려갈기기가 있고, 곰폼이면 후려갈기기
3. 후려갈기기가 없고, 곰폼이면 회복
4. 냥폼이면 칼날 발톱
5. 회복 스킬이 있고, 마우스오버 대상이 아군이면 회복
1. 회복 스킬이 있고, 대상이 아군이면 회복

이제 주문에 따라 매크로를 작성합시다

#showtooltip

/cast [nostance,harm] 천벌

/cast [known:후려갈기기,stance:1] 후려갈기기

/cast [stance:2] 칼날 발톱

/cast [known:회복,@mouseover,help][known:회복,help][] 회복

이렇게 하면 우리는 매크로 버튼 하나로 곰폼, 냥폼, 인간폼과 네가지의 스킬을 한번에 커버할 수 있게 됩니다

그럼 이걸 응용해서 회드를 위한 태양섬광 + 재생 매크로를 한번 만들어 봅시다

하는김에 곰폼 냥폼 스킬도 붙이고, 청명의 전조를 위한 셀프 재생도 우겨 넣어보죠

#showtooltip

/cast [mod:shift,@player] 재생

/cast [spec:1/4,known:태양섬광,stance:0/4,harm] 태양섬광

/cast [stance:1/2] 휘둘러치기

/cast [nostance,@mouseover,help][help][] 재생 

1. 위에부터 차례대로 동작방식을 살펴봅시다
2. 쉬프트키를 누르면 플레이어(자신)에게 재생
3. 전문화 1(조드) 또는 4(회드)이면서, 태양섬광 스킬이 있고, 인간폼 또는 부엉이폼이고, 대상이 적일때 태양섬광
4. 곰폼 또는 냥폼일때 휘둘러치기
5. 인간폼이고, 마우스오버 대상이 아군일때 또는 대상이 아군일때 재생
1. 다른 변신 상태에서도 아군 선택시 바로 재생 캐스팅이 가능하도록 [help]에는 다른 조건을 넣지 않음

논리연산은 매크로 작성 경험이 부족한 초보자 분들이 특히 많이 실수하는 부분입니다

아주 작은 차이로 작동 방식이 완전히 달라지기 때문입니다

/cast [indoors,nostance:2,combat] 표범 변신

/cast [indoors,nostance:2][combat] 표범 변신 

정말 사소한 차이이지만 작동 방식은 완전히 달라집니다

첫번째는 [실내 이면서] [냥폼이 아니면서] [전투중일때] 변신이 가능합니다

두번째는 [실내 이면서] [냥폼이 아닐때] 또는 [전투중일때] 변신이 가능합니다

그래서 첫번째 매크로는 의도와 반대로 실내에서 고양이 변신이 되지 않습니다

전투중이 아니기 때문이지요

STEP>3. 스킬명은 정확하게 기입한다

여긴 설명이 복잡하지 않습니다

말 그대로 스킬명을 정확하게 써야 합니다

대표적인게 사제 스킬에 있습니다

/cast 신의 권능: 방벽

/cast 신의 권능: 고통

/cast 화신: 우르속의 수호자

이처럼 게임 툴팁에 표시되는 문자, 특수문자, 띄어쓰기를 완전히 동일하게 적어 주셔야 매크로가 제대로 인식합니다

많이 실수하는 걸로는 갈퀴발톱 => 갈퀴 발톱, 정신자극 => 정신 자극 등이 있습니다

매크로가 제대로 동작하지 않는다면 스킬명도 꼭 확인해봅시다

중구난방 매크로 작성 팁이었습니다

아래에는 각 상태와 조건에 대한 구문을 정리해 두었습니다

1. 전문화

전문화 창의 순서대로 번호가 붙습니다

[조드] [야드] [수드] [회드]

   1       2       3       4 

2. 폼 구분

스킬바 위의 변신스킬이 나열된 순서대로 폼 번호가 붙습니다

0. 인간형 (변신x)

1. 곰

2. 고양이

3. 날쌘동물 (까마귀 등)

4. 부엉이

이에 대한 조건식은 이렇게 쓰입니다

[nostance] "아무 폼도 아닐때"

[nostance:1] "곰이 아닐때"

[nostance:1/2] "곰 또는 냥이 아닐때"

[stance:1] "곰일때"

[stance:1/2] "곰 또는 냥이 일때" 

3. 마우스오버, 타겟 등 구분

[@mouseover] = 마우스오버 대상

[@target] = 선택대상(생략 가능)

[@player] = 플레이어(자신)

[@cursor] = 마우스 위치 (설치기, 범위기 등)

[harm] = 적 대상 (@target이 포함되어 있음)

[help] = 아군 대상 (@target이 포함되어 있음)

[exsist] = 적/아군 상관없이 (@target이 포함되어 있음)

이에 대한 조합은 다음과 같습니다

[@mouseover,help] 회복

[@player] 탈태 (제자리 탈태)

[@cursor] 꽃피우기

[@mouseover,exsist] 신성 충격 (적아 상관없이 마우스오버에 신성 충격) 

4. known은 왜 쓰는가?

known:스킬명 옵션은 그냥 스킬창이 ?로 도배되는게 싫어서 쓰는......건 제 개인 취향이고

실제로는 레이드와 쐐기 특성이 갈라지는데에 따라 액티브 스킬이 달라질 수 있는데, 그에 대한 한 방편입니다

/cast [known:말살,stance:1] 말살

/cast [known:달 광선,stance:1] 달 광선

이런 식으로 영웅특성이 엘룬이면 달 광선, 발톱의 드루이드면 말살이 나오게끔 하는 방법이 있습니다

이걸 조금 더 응용하면

#showtooltip

/cast [spec:2,known:적응의 무리,stance:2] 적응의 무리

/cast [spec:4,known:세나리온 수호물,@mouseover,help][spec:4,known:세나리온 수호물,help] 세나리온 수호물

/cast [@mouseover,harm][harm][] 달빛섬광

버튼 하나에 3가지 스킬을 넣으면서 특성에 따라 표시하고 안하고까지 조절하는 꼼수도 가능합니다 

액체형상에 대하여...

저는 이런 식으로 키 하나에 할당해서 변신상태를 자동으로 체크해서 액체형상에 쓸 스킬을 넣어놨습니다

마지막은 표범에서 인간형으로 돌아오는 구문입니다

#showtooltip

/cast [spec:1/4,known:별빛쇄도] 별빛쇄도

/cast [spec:2] 원시 분노

/cast [spec:3,known:달 광선] 달 광선

/cast [spec:3,known:갈퀴 발톱] 갈퀴 발톱

/cast [spec:4,noform:2] 갈퀴 발톱

/cast [spec:4,form:2] !표범 변신 

읽어 주셔서 감사합니다